asp 远程图片自动保存到本地服务器

<%
'============================================
'函数作用：远程图片自动保存到本地服务器
'修改时间：2006-7-3 21:21
'传人参数：
' localfilename:本地文件名
' remotefileurl:远程文件url
'============================================

sub saveremotefile(localfilename,remotefileurl)
dim ads,retrieval,getremotedata
set retrieval = server.createobject("microsoft.xmlhttp")
with retrieval
.open "get", remotefileurl, false, "", ""
.send
getremotedata = .responsebody
end with
set retrieval = nothing
set ads = server.createobject("adodb.stream")
with ads
.type = 1
.open
.write getremotedata
.savetofile localfilename,2
.cancel()
.close()
end with
set ads=nothing
end sub

remotefileurl = "http://www.111com.net/bbs/images/mainlogo.gif" '获取远程图片
fileext = right(remotefileurl,4) '获取远程图片的格式

randomize
rannum = int(9*10^3*rnd)+10^3
dtnow = now()
filename = year(dtnow) & right("0" & month(dtnow),2) & right("0" & day(dtnow),2) & right("0" & hour(dtnow),2) & right("0" & minute(dtnow),2) & right("0" & second(dtnow),2) & rannum & fileext

localfilename = "./" '保存本地路径
if right(localfilename,1) <> "/" then localfilename = localfilename & "/"
savefile = server.mappath(localfilename & filename)
saveremotefile savefile,remotefileurl '保存远程图片
response.write "保存成功，点击查看图片文件...."
%>